Logo Axel Ebert Technology

Source Code Listing Programm STAB
Source Code Listing Prozedur PROC.STAB
Beispiel für eine Ergebnisdatei STAB.DTA

Source Code Listing Programm STAB

stab.zip Source Code Programm STAB, Prozedur zur PROCSTAB und Ergebnisdatei STAB.DTA [ZIP 11.6 kB] updated 28-Dez-2011

      PROGRAM STAB
C     PROGRAMSOURCE: STAB.SRC                     (AXEL EBERT, MAI 1992)
C
C     BESTIMMUNG DER STABILITAETSGRENZE FUER AXIALVERDICHTER NACH VIER
C     VERSCHIEDENEN KRITERIEN:
C     FUER EINZELNE GITTER NACH LIEBLEIN;
C     FUER EINZELNE STUFEN NACH KOCH UND NACH EINEM ANSATZ VON TRAUPEL;
C     FUER DIE GESAMTE BESCHAUFELUNG NACH DER LAGE DES MAXIMALEN
C     ISENTROPEN WIRKUNGSGRADS
C
C     ZUR RICHTIGEN INTERPRETATION DER ERGEBNISSE IST ES ERFORDERLICH,
C     DASS 3 - 10 BETRIEBSPUNKTE VORGEGEBEN WERDEN UND ALLE BEI GLEICHER
C     DREHZAHL LIEGEN
C
C     AUSGEGEBEN WIRD DER MASSENSTROM AN DER STABILITAETSGRENZE
C     ==>DER WERT IST NUR GUELTIG, WENN ER IM BEREICH DER VORGEGEBENEN
C     MASSENSTROEME LIEGT; ALLE ERGEBNISSE WERDEN ZUSAETZLICH IN EINER
C     DATEI STAB.DTA ABGELEGT
C
C     PROGRAMMSTART: UEBER PROZEDUR PROC.STAB WEGEN DATEIARBEIT
C
C*******BESCHREIBUNG****************************************************
C
C     ALLE AERODYNAMISCHEN CHARAKTERISTIKEN WERDEN AUS DER EINGABE- BZW.
C     ERGEBNISDATEI DES KENNFELDRECHENPROGRAMMS HT0 300 VON DYNATECH
C     (1970) EINGELESEN
C
C     ALLE WINKEL BEZIEHEN SICH AUF MERIDIONALE STROEMUNGSRICHTUNG
C
C     1 EINTRITTSKANTE SCHAUFEL
C     2 AUSTRITTSKANTE SCHAUFEL
C     I INNEN
C     A AUSSEN
C
C     LA,LE BEDEUTEN LAUFRAD,LEITRAD
C     Z.B.: HI LA02 = HINTER LAUFRAD 2; HI LE00 = HINTER VORLEITRAD
C
C     BE      STROEMUNGSWINKEL BETA: ABSOL. FUER LE BZW. RELAT. FUER LA
C     BES     AEQUIVAL. SCHAUFELWINKEL BETAS: ABSOL.F. LE, RELAT. F. LA
C     C       ABS. STROEMUNGSGESCHW.: IM PROGRAMM IST C GLEICH V FUER LE
C     C10-C44 KONSTANTEN ZUR INTERPOLATION VON KOCH - KRITERIEN
C     CA      C IN AXIALER RICHTUNG
C     CAM     CAMBER (WOELBUNGSWINKEL) BES1 - BES2
C     CH      ENTHALPIEKOEFFIZIENT NACH C.C.KOCH
C     CHZUL   ZULAESSIGER WERT FUER CH
C     CM      C IN MERIDIONALER RICHTUNG (IM PROGRAMM NICHT IN GEBRAUCH)
C     CU      C IN UMFANGSRICHTUNG       (IM PROGRAMM NICHT IN GEBRAUCH)
C     DEQ     AEQUIVAL. DIFFUSIONSFAKTOR NACH S.LIEBLEIN
C     DEQZUL  ZULAESSIGER WERT FUER DEQ
C     DHG     RADIALSPIEL (1% DER SCHAUFELHOEHE), BEZOGEN AUF G
C     DZ      AXIALSPALT ZWISCHEN 2 UND 1
C     DZT     DZ, BEZOGEN AUF T
C     ETAS    ISENTROPER WIRKUNGSGRAD
C     FE      FAKTOR ZUR BESTIMMUNG DER EFFEKT. KIN. ENERGIE NACH KOCH
C     G       SCHAUFELKANALWEITE
C     GASR    GASKONSTANTE FUER LUFT = 287.22 J/(KG*K)
C     IN      INZIDENZWINKEL BE1-BES1
C     INREF   REFERENZWERT VON IN FUER STROEMUNG MIT MIN. VERLUSTEN
C     L       LAENGE DER KREISBOGENFOERMIGEN SKELETTLINIE EINES PROFILS,
C             DAS DIESELBE WOELBUNG WIE DAS ENTSPR.NACA65 PROFIL BESITZT
C     LG      GEWICHTETER MITTELWERT VON L/G2 AUS LA UND LE - DATEN
C     M       MASSENSTROM FUER DEN BETRIEBSPUNKT
C     MK      KRITISCHER MASSENSTROM NACH KOCH
C     ML      KRITISCHER MASSENSTROM NACH LIEBLEIN
C     MT      KRITISCHER MASSENSTROM NACH TRAUPEL
C     MW      KRITISCHER MASSENSTROM NACH WIRKUNGSGRADKRITERIUM
C     MX      MASSENSTROM ZW.BENACHBARTEN STROMLINIEN; J=10 IST INTEGRAL
C     NDT     ZAHL DER VORGABEN EINER GROESSE UEBER R IN EINGABEDATEI
C     NGI     ZAHL DER GITTER = NLA + NLE + NL0 < 51
C     NLA     ZAHL DER LAUFRAEDER
C     NLE     ZAHL DER LEITRAEDER
C     NL0     ZAHL DER VORLEITRAEDER
C     NM      ZAHL DER ZU BERECHNENDEN BETRIEBSPUNKTE < 6
C     NMI     NUMMER DER MITTLEREN STROMLINIE   {FUER MITTELSCHNITTDATEN
C     NSCH    SCHAUFELZAHL PRO RAD
C     NSTA    STATIONSZAHL JE STROMLINIE
C     NSTR    ZAHL DER STROMLINIEN J < 10; J = 10 IST INTEGRIERTER WERT
C     PHI     LIEFERZAHL FUER EINE STUFE CA2/U2|NMI
C     PHIMIN  PHI, DASS SICH AUS PSIZUL ERGIBT
C     PIT     GESAMTDRUCKVERHAELTNIS DER BESCHAUFELUNG
C     PK      PIT FUER MK
C     PL      PIT FUER ML
C     PT      PIT FUER MT
C     PW      PIT FUER MW
C     PSI     DRUCKZAHL DELTA(STAT.ENTH.BEI S=CONST)|STUFE/(U2*U2)*2|NMI
C     PSIZUL  MAXIMAL MOEGL. DRUCKZAHL FUER DIE UNGUENSTIGSTE STROMLINIE
C     PSTAT   STATISCHER DRUCK AM GITTERAUSTRITT
C     R       RADIUS
C     RE      REYNOLDSZAHL AUS S UND W1
C     RHO     DICHTE AUS PSTAT UND TSTAT FUER IDEALES GAS
C     S       SEHNENLAENGE
C     SO      SOLIDITY S/T (SCHAUFELDICHTE)
C     SPD     SPEED (DREHZAHL IN U/MIN)
C     SPF     SPEEDFACTOR FUER BETRIEBSP. (DREHZAHL/AUSLEGUNGSDREHZAHL)
C     T       TEILUNG = 2*PI*R/NSCH
C     TSTAT   STATISCHE TEMPERATUR AM GITTERAUSTRITT
C     U       SCHAUFELGESCHWINDIGKEIT
C     V       STROEMUNGSGESCHWINDIGKEIT: ABSOL. FUER LE, RELAT. FUER LA
C     VID     DYNAMISCHE VISKOSITAET, IM BETRIEBSBER. NUR VON TSTAT ABH.
C     VX,VY   EINDIMENSIONALE HILFSFELDER ZUR INTERPOLATION
C     XKRIT   HILFSGROESSE ZUR INTERPOLATION
C     YMAX    HILFSGROESSE ZUR INTERPOLATION
C     W       REL. STROEMUNGSGESCHW.:IM PROGRAMM IST W GLEICH V FUER LA
C     Z       AXIALE KOORDINATE DER SCHAUFELKANTE
C     $EBENE  STRING ZUR BESCHREIBUNG DER STATIONSEBENE, Z.B. HI LA02
C     $K      STRING ZUR BESCHREIBUNG DER KRITISCHEN STUFE NACH KOCH
C     $L      STRING ZUR BESCHREIBUNG DES KRITISCHEN GITTERS NACH LIEBL.
C     $STUFE  STRING ZUR BESCHREIBUNG DER BETRACHTETEN STUFE
C     $T      STRING ZUR BESCHREIBUNG DER KRITISCHEN STUFE NACH TRAUPEL
C     $TYP    STRING ZUR BESCHREIBUNG DES VERDICHTERTYPS
C
C
C     FELD " VALG " FUER DYNATECH ERGEBNISSE
C     =====================================
C      VALG(I, 1,J) = RDATA (RADIUS)   EINGABE
C      VALG(I, 2,J) = BETAS1           EINGABE          F(RDATA)
C      VALG(I, 3,J) = BETAS2           EINGABE          F(RDATA)
C      VALG(I, 4,J) = CAMBER           EINGABE          F(RDATA)
C      VALG(I, 5,J) = STAGGER          EINGABE          F(RDATA)
C      VALG(I, 6,J) = CHORD (SEHNENL.) EINGABE          F(RDATA)
C      VALG(I, 7,J) = D/L              EINGABE          F(RDATA)
C      VALG(I, 8,J) = RADIUS           INLET
C      VALG(I, 9,J) = RADIUS           OUTLET
C      VALG(I,10,J) = BES1             STROMLINIE       F(RIN)
C      VALG(I,11,J) = BES2             STROMLINIE       F(ROUT)
C      VALG(I,12,J) = CAMBER(BES1-BES2)STROMLINIE       F(STRL)
C      VALG(I,13,J) = STAGGER          STROMLINIE       F(STRL)
C      VALG(I,14,J) = MACH-NO ABS      OUTLET           F(ROUT)
C      VALG(I,15,J) = MACH-NR          CRITICAL         F(RIN)
C      VALG(I,16,J) = DIFFUSION FACT   REF              F(STRL)
C      VALG(I,17,J) = DIFFUSION FACT   ACT              F(STRL)
C      VALG(I,18,J) = INCIDENCE        REF              F(RIN)
C      VALG(I,19,J) = INCIDENCE        ACT              F(RIN)
C      VALG(I,20,J) = STALL                             F(RIN)
C      VALG(I,21,J) = CHOKE                             F(RIN)
C      VALG(I,22,J) = DEVIATION        REF              F(ROUT)
C      VALG(I,23,J) = DEVIATION        ACT              F(ROUT)
C      VALG(I,24,J) = LOSS             TOT              F(RIN)
C      VALG(I,25,J) = LOSS             MIN              F(RIN)
C      VALG(I,26,J) = LOSS             INC              F(RIN)
C      VALG(I,27,J) = LOSS             SHOCK            F(RIN)
C      VALG(I,28,J) = LOSS             TIP              F(RIN)
C      VALG(I,29,J) = VELOCITY = U1    CIRC INLET       F(RIN)
C      VALG(I,30,J) = VELOCITY         RAD              F(ROUT)
C      VALG(I,31,J) = VELOCITY = CA2   AXI              F(ROUT)
C      VALG(I,32,J) = VELOCITY = CM2   MER              F(ROUT)
C      VALG(I,33,J) = VELOCITY = CU2   TAN              F(ROUT)
C      VALG(I,34,J) = VELOCITY = C2    TOT              F(ROUT)
C      VALG(I,35,J) = PRESSURE         TOT              F(ROUT)
C      VALG(I,36,J) = PRESSURE         STA              F(ROUT)
C      VALG(I,37,J) = TEMPERATURE      TOT              F(ROUT)
C      VALG(I,38,J) = TEMPERATURE      STA              F(ROUT)
C      VALG(I,39,J) = FLOW-ANGLE =     INLET            F(RIN)
C                   = AL1|LE ODER B1|LA
C      VALG(I,40,J) = FLOW-ANGLE =     OUTLET           F(ROUT)
C                   = AL2|LE ODER BE2|LA
C      VALG(I,41,J) = FLOW-MACH-NR     INLET            F(RIN)
C      VALG(I,42,J) = FLOW-MACH-NR     OUTLET           F(ROUT)
C      VALG(I,43,J) = FLOW-VELOCITY =  INLET            F(RIN)
C                   = C1|LE ODER W1|LA
C      VALG(I,44,J) = FLOW-VELOCITY =  OUTLET           F(ROUT)
C                   = C2|LE ODER W2|LA
C      VALG(I,45,J) = DE HALLER NR                      F(STRL)
C      VALG(I,46,J) = STA-PRES-RISE    ACT              F(RIN)
C      VALG(I,47,J) = STA-PRES-RISE    PERM             F(RIN)
C      VALG(I,48,J) = STA-PRES-RISE    MAX              F(RIN)
C      VALG(I,49,J) = D-ALPHA FLOW                      F(STRL)
C      VALG(I,50,J) = D-BETA FLOW                       F(STRL)
C      VALG(I,51,J) = VELOCITY = U2    CIRC OUTLET      F(ROUT)
C      VALG(I,52,J) = PI               MASCHINE         F(STRL)
C      VALG(I,53,J) = ETAS (ISENTROP)  MASCHINE         F(STRL)
C      VALG(I,54,J) = ETAP (POLYTROP)  MASCHINE         F(STRL)
C      VALG(I,55,J) = PHI              MASCHINE         F(STRL)
C      VALG(I,56,J) = PSI              MASCHINE         F(STRL)
C      VALG(I,57,J) = PI               GITTER           F(STRL)
C      VALG(I,58,J) = ETAS             GITTER (NUR LA)  F(STRL)
C      VALG(I,59,J) = ETAP             GITTER (NUR LA)  F(STRL)
C      VALG(I,60,J) = PHI ALS CA2/U2   GITTER           F(STRL)
C      VALG(I,61,J) = PSI STA =        GITTER (NUR LA)  F(STRL)
C                   = PSI TOT-(C2*C2-C1*C1)/(U2*U2)*2
C      VALG(I,62,J) = PSI TOT =        GITTER (NUR LA)  F(STRL)
C                   = (U2CU2-U1CU1)/(U2*U2)*2
C      VALG(I,63,J) = PSI STA =        STUFE            F(STRL)
C                   = PSI TOT-{(C2*C2)|LE-(C1*C1)|LA}/(U2*U2)*2
C      VALG(I,64,J) = REACT            STUFE            F(STRL)
C      VALG(I,65,J) = ETAS             STUFE            F(STRL)
C      VALG(I,66,J) = ETAP             STUFE            F(STRL)
C      VALG(I,67,J) = PI               STUFE            F(STRL)
C
C
C*****KONSTANTEN, VARIALBLEN, FELDER FUER DAS PROGRAMM******************
      PARAMETER (
     &C10 =  0.898561702631210535E+01, C11 = -0.565938339569078175E+01,
     &C12 =  0.147086726005759227E+01, C13 = -0.166784928586288669E+00,
     &C14 =  0.701157913610926924E-02, C20 =  0.122200000000000001E+01,
     &C21 = -0.856256246677299648E+01, C22 =  0.132478539783803086E+03,
     &C23 = -0.108587914230019658E+04, C24 =  0.315349991139465391E+04,
     &C30 =  0.111190298907441720E+01, C31 = -0.546464268535693257E+00,
     &C32 =  0.813798357726914251E+00, C33 = -0.393832886690006795E+00,
     &C34 = -0.712911427198331324E-02, C40 =  0.497579288285793109E-01,
     &C41 =  0.576841813488708957E+00, C42 = -0.319106201872386655E+00,
     &C43 =  0.101390012649753086E+00, C44 = -0.128835530946547110E-01,
     &DEQZUL = 2.0, GASR = 287.22, PI = 3.141592653)
      REAL
     &BE1(50,10), BE2(50,10), BES2(50,10), CA2(50,10), CAM(50,10),
     &CH(10,50), CHZUL(10,50), DEQ(10,50,10), DHG, DZ(50,10), DZT,
     &ETAS(10,50,10), FE, G,
     &IN(50,10), INREF(50,10), L, LG,
     &M(10), MK, ML, MT, MW, MX(10), PHI(10,50,10), PHIMIN,
     &PIT(10), PK, PL, PT, PW,
     &PSI(10,50,10), PSIZUL, PSTAT(50,10), R1(10,50,10), R2(10,50,10),
     &RE, RHO(50,10), S(50,10), SA(50), SI(50),
     &SO(50,10), SPD(50), SPF(10), T(50,10),
     &TSTAT(50,10), U1, U2, V1(50,10), VALG(50,67,10),
     &VID, VX(10), VY(10), XKRIT, YMAX,
     &Z1I(50), Z1A(50), Z2I(50), Z2A(50)
      INTEGER
     &I, J, K, LL, NDT(50), NGI, NLA, NLE, NL0, NM, NMI, NSCH(50), NSTA,
     &NSTR
      CHARACTER * (80,V) $K, $L, $T, $TYP, $Z
      CHARACTER * 25 $STUFE(50)
      CHARACTER * 10 $EBENE(50)
      $K='               '
      $L='               '
      $T='               '
C
C*****LESEN DER KOPFZEILEN AUS DEM ERGEBNISFILE DER DYNATECH-RECHNUNG***
C     $(NAME).(TYP).PLOT
      READ(15,'(A)') $TYP
      READ(15,'(5I5)') NSTA,NSTR,NLA,NLE,NL0
      READ(15,'(I5)') NM
      DO 100 LL=1,NM
      READ(15,'(3F12.4)') SPF(LL),M(LL),PIT(LL)
      IF (PIT(LL).LE.0.0) THEN
        WRITE(2,'(A,F8.3,A)')' M = ',M(LL),' NICHT AUSWERTBAR ==> STOP'
        STOP
      ENDIF
  100 CONTINUE
      NGI=NLA+NLE+NL0
      NMI=INT((NSTR+1)/2)
C
C*****LESEN DES EINGABEFILE DER DYNATECH-RECHNUNG $(NAME).(TYP)*********
C     ZUR BESTIMMUNG DER AXIALEN SCHAUFELKOORD.{WICHTIG FUER AXIALSPALTE
C
      DO 110 I=1,5
      READ(16,'(A)') $Z
  110 CONTINUE
      DO 120 LL=1,NM
      READ(16,'(A)') $Z
  120 CONTINUE
      J=0
      DO 130 I=1,NSTA
      READ(16,'(A)') $Z
      IF ($Z(73:73).EQ.'V') THEN
        J=J+1
        READ ($Z( 1:12),'(F12.5)') Z1I(J)
        READ ($Z(37:48),'(F12.5)') Z1A(J)
      ENDIF
      IF ($Z(73:73).EQ.'H') THEN
        READ ($Z( 1:12),'(F12.5)') Z2I(J)
        READ ($Z(37:48),'(F12.5)') Z2A(J)
      ENDIF
  130 CONTINUE
C
C*****SCHLEIFE UM ALLE KENNFELDPUNKTE ZUR BESTIMMUNG DER KRITERIEN******
C     FUER DEN JEWEILIGEN KENNFELDPUNKT
      IF (NM.GT.10) THEN
        NM=10
        WRITE(2,'(A)') ' AUSWERTUNG NUR FUER DIE ERSTEN 10MASSENSTROEME'
      ENDIF
      DO 260 LL = 1,NM
C
C*****EINLESEN DER DATEN DES KENNFELDPUNKTES AUS $(NAME).(TYP).PLOT*****
C     ==> FELD {VALG(I,1,J) - VALG(I,67,J)} FUER J=1 BIS MAX 10
C     I IST DAS GITTER, J EINE AUSGEWAEHLTE STROMLINIE FUER J<10
C     J=10 IST EIN INTEGRIERTER WERT UEBER DIE STROMLINIEN
C     BEI EINGABEGROESSEN {VALG(I,1,J)-VALG(I,7,J)} SIND NUR NDT WERTE
C     UEBER R BELEGT, WOMIT ALSO NICHT ZWINGEND FUER JEDE STROMLINIE
C     VORGABEN GETROFFEN WERDEN MUESSEN
C
      DO 140 I=1,NGI
      READ(15,'(A)') $EBENE(I)
      READ(15,'(2I5,F12.0)') NDT(I),NSCH(I),SPD(I)
      DO 140 K=1,67
      READ(15,'(10F12.0)') (VALG(I,K,J),J=1,10)
  140 CONTINUE
      DO 150 I=1,NGI
      DO 150 J=1,10
      IF(VALG(I,38,J).EQ.0.) GOTO 150
      VALG(I,14,J)=VALG(I,34,J)/SQRT(402.967*VALG(I,38,J))
  150 CONTINUE
C*****ENDE EINLESEN FUER EINEN PUNKT************************************
C
C*****UMSCHREIBUNG DER NOETIGEN GROESSEN FUER DIE STABILITAETSKRITERIEN*
      DO 160 I=1,NGI
      SI(I)       = VALG(I, 6,1)
      SA(I)       = VALG(I, 6,NDT(I))
      DO 160 J=1,NSTR
      R1(LL,I,J)  = VALG(I, 8,J)
      R2(LL,I,J)  = VALG(I, 9,J)
      BES2(I,J)   = VALG(I,11,J)*PI/180.0
      CAM(I,J)    = VALG(I,12,J)*PI/180.0
      INREF(I,J)  = VALG(I,18,J)
      IN(I,J)     = VALG(I,19,J)
      CA2(I,J)    = VALG(I,31,J)
      PSTAT(I,J)  = VALG(I,36,J)*100000.0
      TSTAT(I,J)  = VALG(I,38,J)
      RHO(I,J)    = PSTAT(I,J)/TSTAT(I,J)/GASR
      BE1(I,J)    = ABS(VALG(I,39,J)*PI/180.0)
      BE2(I,J)    = ABS(VALG(I,40,J)*PI/180.0)
      V1(I,J)     = VALG(I,43,J)
  160 CONTINUE
      DO 170 I=1,NGI
      DO 170 J=1,10
      ETAS(LL,I,J)= VALG(I,53,J)
      PHI(LL,I,J) = VALG(I,60,J)*R2(LL,I,J)/R2(LL,I,NMI)
      PSI(LL,I,J) = VALG(I,63,J)*
     &              R2(LL,I,J)*R2(LL,I,J)/(R2(LL,I,NMI)*R2(LL,I,NMI))
  170 CONTINUE
      DO 180 I=1,NL0
      $STUFE(I)='VORLEITRAD'
  180 CONTINUE
      DO 190 I=(1+NL0),NGI,2
      $STUFE(I)='STUFE AUS '//$EBENE(I)(4:7)//' UND '//$EBENE(I+1)(4:7)
      $STUFE(I+1)=$STUFE(I)
  190 CONTINUE
C
C*****BERECHNUNG SEHNENLAENGEN, AXIALSPALTE DURCH INTERPOLATION*********
C     BERECHNUNG TEILUNGEN, SOLIDITIES
      DO 200 I=1,NGI
      DO 200 J=1,NSTR
      S(I,J) = (SA(I)-SI(I))/
     &         (R1(LL,I,NSTR)-R1(LL,I,1))*(R1(LL,I,J)-R1(LL,I,1)) +SI(I)
      T(I,J)   = 2*PI*R1(LL,I,J)/NSCH(I)
      SO(I,J)  = S(I,J)/T(I,J)
  200 CONTINUE
      DO 210 I=1,(NGI-1)
      DO 210 J=1,NSTR
      DZ(I,J) = (Z1A(I+1)-Z1I(I+1))/
     &(R1(LL,I+1,NSTR)-R1(LL,I+1,1))*(R2(LL,I,J)-R1(LL,I+1,1))+Z1I(I+1)
     &    -     (Z2A(I)-Z2I(I))/
     &(R2(LL,I  ,NSTR)-R2(LL,I  ,1))*(R2(LL,I,J)-R2(LL,I  ,1))-Z2I(I)
  210 CONTINUE
C
C*****BERECHNUNG DER AEQUIV.DIFF.-FAKTOREN FUER ALLE STROMLINIEN UND****
C     GITTER NACH LIEBLEIN; DEQ GILT NICHT FUER IN < INREF, IN DIESEN
C     FAELLEN WIRD MIT IN = INREF WEITERGERECHNET UND DEQ < 0 AUSGEGEBEN
      WRITE(2,'(A,F8.3)')' BERECHNUNG DEQ       FUER M =',M(LL)
      DO 220 I=1,NGI
      DO 220 J=1,NSTR
      IF (IN(I,J).LT.INREF(I,J)) THEN
      DEQ(LL,I,J)= -COS(BE2(I,J))/COS(BE1(I,J))*
     &(1.12 +                                     0.61*COS(BE1(I,J))*
     &COS(BE1(I,J))/SO(I,J)*(TAN(BE1(I,J))-TAN(BE2(I,J))))
      ELSE
      DEQ(LL,I,J)=  COS(BE2(I,J))/COS(BE1(I,J))*
     &(1.12 + 0.0117*(IN(I,J)-INREF(I,J))**1.43 + 0.61*COS(BE1(I,J))*
     &COS(BE1(I,J))/SO(I,J)*(TAN(BE1(I,J))-TAN(BE2(I,J))))
      ENDIF
  220 CONTINUE
C
C*****BERECHNUNG DER INTEGRALEN PHI UND PSI FUER ALLE STUFEN NACH DER***
C     VORSCHRIFT VON TRAUPEL (CHARAKTERISTIKEN BEZIEHEN SICH AUF U2|NMI
C     UND KLAMMERN DEN WANDNAHEN BEREICH AUS)
C     DA CAX MIT DEM BLOCKIERUNGSFAKTOR KORRIGIERT WIRD, ERGAEBE EINE
C     AUFSUMMIERUNG ALLER MX(J) EIN ZU GROSSES M, IM KERNBEREICH DER
C     STROEMUNG TRIFFT CAX UND MX(J) ABER UMSO GENAUER ZU
      WRITE(2,'(A,F8.3)')' BERECHNUNG PHI,  PSI FUER M =',M(LL)
      DO 240 I=1,NGI
      PHI(LL,I,10)=0.0
      PSI(LL,I,10)=0.0
      MX(10)=0.0
      DO 230 J=3,(NSTR-1)
      MX(J)=(CA2  (I,J)+CA2  (I,J-1))*0.5*
     &      (RHO  (I,J)+RHO  (I,J-1))*0.5*
     &   PI*(R2(LL,I,J)*R2(LL,I,J)-R2(LL,I,J-1)*R2(LL,I,J-1))
      MX(10)=MX(10)+MX(J)
  230 CONTINUE
      DO 240 J=3,(NSTR-1)
      PHI(LL,I,10)=PHI(LL,I,10) +
     &             MX(J)/MX(10)*0.5*(PHI(LL,I,J)+PHI(LL,I,J-1))
      PSI(LL,I,10)=PSI(LL,I,10) +
     &             MX(J)/MX(10)*0.5*(PSI(LL,I,J)+PSI(LL,I,J-1))
  240 CONTINUE
C
C*****BERECHNUNG DES ENTHALPIEKOEFFIZIENTEN FUER ALLE STUFEN IM*********
C     MITTELSCHNITT NACH KOCH
      WRITE(2,'(A,F8.3)')' BERECHNUNG CH, CHZUL FUER M =',M(LL)
      DO 250 I=(1+NL0),NGI,2
      L=S(I,NMI)*0.5*CAM(I,NMI)/SIN(0.5*CAM(I,NMI))
      G=T(I,NMI)*COS(BES2(I,NMI))
      DHG=G
      LG=L/G*V1(I,NMI)*V1(I,NMI)
      L=S(I+1,NMI)*0.5*CAM(I+1,NMI)/SIN(0.5*CAM(I+1,NMI))
      G=T(I+1,NMI)*COS(BES2(I+1,NMI))
      DHG=0.5*(DHG+G)
      LG=LG + L/G*V1(I+1,NMI)*V1(I+1,NMI)
      LG=LG/ (V1(I,NMI)*V1(I,NMI)+V1(I+1,NMI)*V1(I+1,NMI))
      IF (LG.LT.0.308.OR.LG.GT.2.883) THEN
        WRITE(2,'(A,F8.3,A)') ' EXTRAPOLATION: LG = ',LG,' '//$STUFE(I)
      ENDIF
      CHZUL(LL,I)=C40+C41*LG+C42*LG**2+C43*LG**3+C44*LG**4
      U2=CA2(I,NMI)/PHI(LL,I,NMI)
      U1=U2*R1(LL,I,NMI)/R2(LL,I,NMI)
      CH(LL,I)=(PSI(LL,I+1,NMI)*U2*U2 - U2*U2 + U1*U1)/
     &(V1(I  ,NMI)*V1(I  ,NMI)*FE(PI,R1(LL,I  ,NMI),R2(LL,I  ,NMI),
     &           BE1(I  ,NMI),V1(I  ,NMI),CA2(I  ,NMI),PHI(LL,I  ,NMI))+
     & V1(I+1,NMI)*V1(I+1,NMI)*FE(PI,R1(LL,I+1,NMI),R2(LL,I+1,NMI),
     &           BE1(I+1,NMI),V1(I+1,NMI),CA2(I+1,NMI),PHI(LL,I+1,NMI)))
      IF (I.EQ.1) THEN
        VID=1.71E-05*(TSTAT(I,NMI)/273.15)**0.72
        RE=V1(I,NMI)*S(I,NMI)*RHO(I  ,NMI)/VID
      ELSE
        VID=1.71E-05*(TSTAT(I-1,NMI)/273.15)**0.72
        RE=V1(I,NMI)*S(I,NMI)*RHO(I-1,NMI)/VID
      ENDIF
      RE=LOG10(RE)
      IF (RE.LT.5.114.OR.RE.GT.7.000) THEN
        WRITE(2,'(A,F8.3,A)')' EXTRAPOLATION:LOG10(RE)=',RE,$STUFE(I)
      ENDIF
      CH(LL,I)=CH(LL,I)/(C10+C11*RE+C12*RE**2+C13*RE**3+C14*RE**4)
      DHG=(R2(LL,I,NSTR)-R2(LL,I,1))*0.01/DHG
      IF (DHG.LT.0.000.OR.DHG.GT.0.150) THEN
        WRITE(2,'(A,F8.3,A)') ' EXTRAPOLATION:DHG =',DHG,' '//$STUFE(I)
      ENDIF
      CH(LL,I)=CH(LL,I)/(C20+C21*DHG+C22*DHG**2+C23*DHG**3+C24*DHG**4)
      DZT=DZ(I,NMI)/T(I,NMI)
      IF (DZT.LT.0.100.OR.DZT.GT.0.800) THEN
        WRITE(2,'(A,F8.3,A)') ' EXTRAPOLATION:DZT =',DZT,' '//$STUFE(I)
      ENDIF
      CH(LL,I)=CH(LL,I)/(C30+C31*DZT+C32*DZT**2+C33*DZT**3+C34*DZT**4)
  250 CONTINUE
C
  260 CONTINUE
C*****ENDE SCHLEIFE UM ALLE KENNFELDPUNKTE (BESTIMMUNG DER KRITERIEN****
C     FUER DEN JEWEILIGEN PUNKT)
C
      WRITE(2,'(A)')' *VERGLEICH UNTER ALLEN MASSENSTROEMEN*'
C*****BESTIMMUNG DES KRITISCHEN MASSENSTROMES NACH LIEBLEIN*************
      WRITE(2,'(A)')' KRITISCHER MASSENSTROM NACH LIEBLEIN'
      ML=0.0
      DO 280 LL=1,NM
      DO 280  I=1,NGI
      K=0
      DO 270  J=1,NSTR
      IF (DEQ(LL,I,J).GE.DEQZUL) THEN
        K=K+1
      ENDIF
  270 CONTINUE
      IF (3*K.GT.NSTR) THEN
        IF (M(LL).GT.ML) THEN
          ML=M(LL)
          $L=$EBENE(I)
        ENDIF
      ENDIF
  280 CONTINUE
      CALL IP2(NM,M,PIT,ML,PL)
      WRITE(2,'(A,F8.3,A)') ' ML =',ML,' KG/S  '//$L
C
C*****BESTIMMUNG DES KRITISCHEN MASSENSTROMES NACH TRAUPEL**************
      WRITE(2,'(A)')' KRITISCHER MASSENSTROM NACH TRAUPEL'
      MT=0.0
      DO 300 I=(1+NL0),NGI,2
      DO 300 J=2,(NSTR-1)
      DO 290 LL=1,NM
      VX(LL)=PHI(LL,I,J)
      VY(LL)=PSI(LL,I+1,J)
  290 CONTINUE
      CALL IP2MAX(NM,VX,VY,PHIMIN,PSIZUL)
      IF (PSIZUL.GT.0.0) THEN
        CALL IP2(NM,VX,M,PHIMIN,YMAX)
        IF (YMAX.GT.MT) THEN
          MT=YMAX
          $T=$STUFE(I)
        ENDIF
      ENDIF
  300 CONTINUE
      CALL IP2(NM,M,PIT,MT,PT)
      WRITE(2,'(A,F8.3,A)') ' MT =',MT,' KG/S  '//$T
C
C*****BESTIMMUNG DES KRITISCHEN MASSENSTROMES NACH KOCH*****************
C     ES WIRD DER QUOTIENT AUS CH/CHZUL GEBILDET UND UEBER INTERPOLATION
C     DER GROESSTE MASSENSTROM GESUCHT, BEI DEM CH/CHZUL = 1 IST
      WRITE(2,'(A)')' KRITISCHER MASSENSTROM NACH KOCH'
      MK=0.0
      DO 320  I=(1+NL0),NGI,2
      DO 310 LL=1,NM
        VY(LL)=CH(LL,I)/CHZUL(LL,I)
  310 CONTINUE
      CALL IP2CH1(NM,M,VY,XKRIT,1.0)
      IF (XKRIT.GT.MK) THEN
        MK=XKRIT
        $K=$STUFE(I)
      ENDIF
  320 CONTINUE
      CALL IP2(NM,M,PIT,MK,PK)
      WRITE(2,'(A,F8.3,A)') ' MK =',MK,' KG/S  '//$K
C
C*****BESTIMMUNG DES KRITISCHEN MASSENSTROMES AUS DEM MAXIMUM VON ETAS**
      WRITE(2,'(A)')' KRITISCHER MASSENSTROM NACH WIRKUNGSGRAD'
      MW=0.0
      DO 330 LL=1,NM
      VY(LL)=ETAS(LL,NGI,10)
  330 CONTINUE
      CALL IP2MAX(NM,M,VY,XKRIT,YMAX)
      IF (XKRIT.GT.MW) THEN
        MW=XKRIT
      ENDIF
      CALL IP2(NM,M,PIT,MW,PW)
      WRITE(2,'(A,F8.3,A)') ' MW =',MW,' KG/S'
C
C*****ABSPEICHERN DER ERGEBNISSE IN DER DATEI $(NAME).(TYP).STAB.DTA****
      WRITE( 2,'(A)')' ERGEBNISSE IN DATEI $(NAME).(TYP).STAB.DTA'
      WRITE(17,'(A)')'DATEN ZUR BEURTEILUNG DER STABILITAETSGRENZE FUER
     &AXIALVERDICHTER NACH DEM PROGRAMM STAB.SRC'
      WRITE(17,'(A)') $TYP
      WRITE(17,'(A)') 'PUNKT     SPF         M           PIT'
      DO 340 LL=1,NM
      WRITE(17,'(I3,3F12.4)') LL,SPF(LL),M(LL),PIT(LL)
  340 CONTINUE
      WRITE(17,'(A)')  'DATEN FUER DIE KRITERIEN VON LIEBLEIN UND TRAUPE
     &L:'
      DO 370 I=1,NGI
      WRITE(17,'(A)') $EBENE(I)
      WRITE(17,'(A)')'     ---------M1----------- ---------M2-----------
     & ---------M3----------- ---------M4----------- ---------M5--------
     &----'
      WRITE(17,'(A)')'STRL    R2  DEQ  PHI PSISTU    R2  DEQ  PHI PSISTU
     &    R2  DEQ  PHI PSISTU    R2  DEQ  PHI PSISTU    R2  DEQ  PHI PSI
     &STU '
      DO 350 J=1,NSTR
      WRITE(17,'(I3,5(F8.2,3F5.2))') J,(R2(LL,I,J),DEQ(LL,I,J),
     &PHI(LL,I,J),PSI(LL,I,J),LL=1,5)
  350 CONTINUE
      WRITE(17,'(A,F6.2,3F5.2,4(F8.2,3F5.2))') 'INTEG',(R2(LL,I,10),
     &DEQ(LL,I,10),PHI(LL,I,10),PSI(LL,I,10),LL=1,5)
      WRITE(17,'(A)')'     ---------M6----------- ---------M7-----------
     & ---------M8----------- ---------M9----------- ---------M10-------
     &----'
      WRITE(17,'(A)')'STRL    R2  DEQ  PHI PSISTU    R2  DEQ  PHI PSISTU
     &    R2  DEQ  PHI PSISTU    R2  DEQ  PHI PSISTU    R2  DEQ  PHI PSI
     &STU '
      DO 360 J=1,NSTR
      WRITE(17,'(I3,5(F8.2,3F5.2))') J,(R2(LL,I,J),DEQ(LL,I,J),
     &PHI(LL,I,J),PSI(LL,I,J),LL=6,NM)
  360 CONTINUE
      WRITE(17,'(A,F6.2,3F5.2,4(F8.2,3F5.2))') 'INTEG',(R2(LL,I,10),
     &DEQ(LL,I,10),PHI(LL,I,10),PSI(LL,I,10),LL=6,NM)
  370 CONTINUE
      WRITE(17,'(A)')'                          ---------M1------- -----
     &----M2------- ---------M3------- ---------M4------- ---------M5---
     &----'
      WRITE(17,'(A)')'                          ---------M6------- -----
     &----M7------- ---------M8------- ---------M9------- ---------M10--
     &----'
      WRITE(17,'(A)')'KOCHKRITERIUM:               CHZUL    CH        CH
     &ZUL    CH        CHZUL    CH        CHZUL    CH        CHZUL   CH'
      DO 380 I=(1+NL0),NGI,2
      WRITE(17,'(A,F9.3,F8.3,4(F11.3,F8.3))')$STUFE(I),
     &     (CHZUL(LL,I),CH(LL,I),LL=1,5)
      WRITE(17,'(A,F9.3,F8.3,4(F11.3,F8.3))')$STUFE(I),
     &     (CHZUL(LL,I),CH(LL,I),LL=6,NM)
  380 CONTINUE
      WRITE(17,'(A)')'                          ---------M1------- -----
     &----M2------- ---------M3------- ---------M4------- ---------M5---
     &----'
      WRITE(17,'(A)')'                          ---------M6------- -----
     &----M7------- ---------M8------- ---------M9------- ---------M10--
     &----'
      WRITE(17,'(A,F14.4,4F19.4)') 'ETAS DER BESCHAUFELUNG ==>',
     &     (ETAS(LL,NGI,10),LL=1,5)
      WRITE(17,'(A,F14.4,4F19.4)') '                          ',
     &     (ETAS(LL,NGI,10),LL=6,NM)
      WRITE(17,'(A)') 'STABILITAETSGRENZE: '
      WRITE(17,'(2(A,F8.3),A)')'NACH LIEBLEIN INSTABIL BIS ML =',ML,
     &' KG/S UND PIT =',PL,'  '//$L//
     &'(NAECHST GROESSERES VORGEGEBENES M IST STABIL)'
      WRITE(17,'(2(A,F8.3),A)')'NACH   KOCH   GRENZE   BEI MK =',MK,
     &' KG/S UND PIT =',PK,'  '//$K
      WRITE(17,'(2(A,F8.3),A)')'NACH  TRAUPEL GRENZE   BEI MT =',MT,
     &' KG/S UND PIT =',PT,'  '//$T
      WRITE(17,'(2(A,F8.3))')  'NACH  ETASMAX GRENZE   BEI MW =',MW,
     &' KG/S UND PIT =',PW
C
C*****VORBEREITUNG VON PLOTTDATEIEN*************************************
      K=17
      DO 390 I=(1+NL0),NGI,2
      K=K+1
      CALL PLOT (NM,NSTR,K,I,PHI,PSI)
  390 CONTINUE
C
      STOP
      END
C#####ENDE HAUPTPROGRAMM################################################
C#####UNTERPROGRAMME####################################################
      REAL FUNCTION FE(PI,R1,R2,BE1,V1,CA2,PHI)
C*****KOEFFIZIENT ZUR BESTIMMUNG DER EFFEKT.KIN.ENERGIE NACH KOCH*******
C     FE = V1EFF^2/V1^2
      REAL BE1, CA2, PHI, PI, R1, R2, V1, U1, U2, X
      U2=CA2/PHI
      U1=U2*R1/R2
C     X WIRD NACHFOLGEND BENUTZT, UM CM1=WM1 ZU BESTIMMEN
      X=COS(BE1)*V1
C     X WIRD NACHFOLGEND BENUTZT, UM STROEM.WINKEL IM ANDEREN BEZUGS-
C     SYSTEM ZU BESTIMMEN
      X=ATAN((U1-SIN(BE1)*V1)/X)
C     X WIRD ZUM ANTEIL VON FE
      IF     (X     .LT.    0.0) THEN
        X=0.625*U1*U1/(V1*V1)
      ELSEIF (X+BE1 .GT. 0.5*PI) THEN
        X=0.625
      ELSE
        X=0.625*SIN(X+BE1)*SIN(X+BE1)
      ENDIF
      FE=0.25+X+0.125*U1*U1/(V1*V1)
      END
C
      SUBROUTINE PLOT (NM,NSTR,DEV,GITTER,PHI,PSI)
C*****ANLEGEN EINER PLOTDATEI FUER SEPARATE PSI/PHI KENNLINIEN (1 STUFE)
      REAL PHI(10,50,10), PSI(10,50,10)
      INTEGER DEV,J,LL,NM,NSTR,GITTER
      CHARACTER * (80,V) $STR
      DO 100 J=2,(NSTR-1)
      WRITE($STR,'(I1)') NM
      WRITE(DEV,'(A)') $STR//', 1, 1, 1'
      WRITE($STR,'(I1)') J
      WRITE(DEV,'(A)') ''''//$STR//''''
      DO 100 LL=1,NM
      WRITE(DEV,'(2F12.8)') PHI(LL,GITTER,J), PSI(LL,(GITTER+1),J)
  100 CONTINUE
      END
C
      SUBROUTINE IP2MAX (NM,VX,VY,XKRIT,YMAX)
C*****BESTIMMUNG DES MAXIMUMS INNERHALB VY MIT POLYNOM 2. GRADES********
C     SIND WENIGER ALS DREI WERTEPAARE VORHANDEN ODER LIEGT DAS MAXIMUM
C     AM RANDE DES INTERVALLS, SO WIRD MAXIMUM = 0 AUSGEGEBEN
C     XKRIT IST DER KORRESPONDIERENDE WERT ZU YMAX
      REAL G1, G2, X, XKRIT, Y, YMAX, VX(10), VY(10)
      INTEGER K,LL,M,N,NM
      XKRIT=0.0
      YMAX=0.0
      K   =0
      M   =0
      IF (NM.GT.2) THEN
        DO 100 LL=1,NM
        IF (VY(LL).GT.YMAX) THEN
          YMAX=VY(LL)
          M=LL
        ENDIF
  100   CONTINUE
        IF     (M.LT.   2) THEN
          M=2
          K=1
        ELSEIF (M.GT.NM-1) THEN
          M=NM-1
          K=1
        ENDIF
        G1= (VY(M  )-VY(M-1))/(VX(M  )-VX(M-1))
        G2=((VY(M+1)-VY(M-1))/(VX(M+1)-VX(M-1)) - G1)/(VX(M+1)-VX(M))
        DO 110 N=0,100
        X=VX(M-1)+N*(VX(M+1)-VX(M-1))/100
        Y=(G2*(X-VX(M))+G1)*(X-VX(M-1)) + VY(M-1)
        IF (Y.GE.YMAX) THEN
          XKRIT=X
          YMAX =Y
        ENDIF
  110   CONTINUE
        IF (K.EQ.1) THEN
          XKRIT=0.0
          YMAX=0.0
        ENDIF
      ENDIF
      END
C
      SUBROUTINE IP2CH1 (NM,VX,VY,XKRIT,YMAX)
C*****INTERPOLATION FUER DAS KOCHKRITERIUM MIT POLYNAOM 2. GRADES*******
C     YMAX IST DER MAXIMAL ZULAESSIGE Y-WERT, DER UEBER X NATUERLICH
C     AUCH MEHRMALS AUFTRETEN KANN; DAS GROESSTE SO ZU YMAX ERMITTELTE X
C     WIRD ALS XKRIT UEBERGEBEN
      REAL G1, G2, X, XKRIT, Y, YMAX, VX(10), VY(10)
      INTEGER K,LL,N,NM
      XKRIT=0.0
      IF (NM.GT.2) THEN
        DO 120 K=0,100
        X=VX(1)+K*(VX(NM)-VX(1))/100
C       BESTIMMUNG VON N = LAGE VON X
        N=0
        IF (VX(2).GE.VX(1)) THEN
          DO 100 LL=1,NM
            IF (X.GT.VX(LL)) THEN
              N=LL
            ENDIF
  100     CONTINUE
        ELSE
          DO 110 LL=1,NM
            IF (X.LT.VX(LL)) THEN
              N=LL
            ENDIF
  110     CONTINUE
        ENDIF
        IF (N.GT.NM-2) THEN
          N=NM-2
        ENDIF
        G1= (VY(N+1)-VY(N))/(VX(N+1)-VX(N))
        G2=((VY(N+2)-VY(N))/(VX(N+2)-VX(N))-G1)/(VX(N+2)-VX(N+1))
        Y=(G2*(X-VX(N+1))+G1)*(X-VX(N)) + VY(N)
        IF (Y.GE.YMAX) THEN
          IF (X.GT.XKRIT) THEN
            XKRIT=X
          ENDIF
        ENDIF
  120   CONTINUE
        IF (XKRIT.GT.0.0) THEN
          XKRIT=XKRIT + ABS(VX(NM)-VX(1))/100
        ENDIF
      ENDIF
      END
C
      SUBROUTINE IP2 (NM,VX,VY,X,Y)
C*****BESTIMMUNG Y(X) AUS DEN FELDERN VX,VY MIT POLYNOM 2. GRADES*******
C     BEI VORGABE VON X=0 WIRD Y=0 AUSGEGEBEN
C     MUSS EXTRAPOLIERT ODER LINEAR INTERPOLIERT WERDEN, SO WIRD NUR AM
C     BILDSCHIRM DARAUF HINGEWIESEN
C
      REAL G1, G2, X, Y, VX(10), VY(10)
      INTEGER LL, N, NM
      Y=0.0
      IF (X.NE.0.0) THEN
       IF (NM.GT.2) THEN
C       BESTIMMUNG VON N = LAGE VON X
        N=0
        IF (VX(2).GE.VX(1)) THEN
          DO 100 LL=1,NM
            IF (X.GT.VX(LL)) THEN
              N=LL
            ENDIF
  100     CONTINUE
        ELSE
          DO 110 LL=1,NM
            IF (X.LT.VX(LL)) THEN
              N=LL
            ENDIF
  110     CONTINUE
        ENDIF
        IF     (N.LT.  1) THEN
          N=1
        ELSEIF (N.GT.NM-2) THEN
          N=NM-2
        ENDIF
        IF (X.LT.VX(1).AND.X.LT.VX(NM)) THEN
          WRITE(2,'(A,F8.3,A)') ' EXTRAPOLATION: X = ',X,' ZU KLEIN'
        ENDIF
        IF (X.GT.VX(1).AND.X.GT.VX(NM)) THEN
          WRITE(2,'(A,F8.3,A)') ' EXTRAPOLATION: X = ',X,' ZU GR0SS'
        ENDIF
        G1= (VY(N+1)-VY(N))/(VX(N+1)-VX(N))
        G2=((VY(N+2)-VY(N))/(VX(N+2)-VX(N))-G1)/(VX(N+2)-VX(N+1))
        Y=(G2*(X-VX(N+1))+G1)*(X-VX(N)) + VY(N)
      ENDIF
      ENDIF
      END
C

↑ Seitenanfang

Source Code Listing Prozedur PROC.STAB

/PROC N ,(&NAME,&TYP),SUBDTA=&
/REMARK &NAME
/REMARK &TYP
/FILE $&NAME..&TYP..PLOT,LINK=DSET15,FCBTYPE=SAM
/FILE $&NAME..&TYP.,LINK=DSET16,FCBTYPE=SAM
/FILE $&NAME..&TYP..STAB.DTA,LINK=DSET17,FCBTYPE=SAM
/FILE #STAB.PLOT.1,LINK=DSET18,FCBTYPE=SAM
/FILE #STAB.PLOT.2,LINK=DSET19,FCBTYPE=SAM
/FILE #STAB.PLOT.3,LINK=DSET20,FCBTYPE=SAM
/FILE #STAB.PLOT.4,LINK=DSET21,FCBTYPE=SAM
/FILE #STAB.PLOT.5,LINK=DSET22,FCBTYPE=SAM
/FILE #STAB.PLOT.6,LINK=DSET23,FCBTYPE=SAM
/FILE #STAB.PLOT.7,LINK=DSET24,FCBTYPE=SAM
/FILE #STAB.PLOT.8,LINK=DSET25,FCBTYPE=SAM
/FILE #STAB.PLOT.9,LINK=DSET26,FCBTYPE=SAM
/FILE #STAB.PLOT.10,LINK=DSET27,FCBTYPE=SAM
/FILE #STAB.PLOT.11,LINK=DSET28,FCBTYPE=SAM
/FILE #STAB.PLOT.12,LINK=DSET29,FCBTYPE=SAM
/FILE #STAB.PLOT.13,LINK=DSET30,FCBTYPE=SAM
/FILE #STAB.PLOT.14,LINK=DSET31,FCBTYPE=SAM
/FILE #STAB.PLOT.15,LINK=DSET32,FCBTYPE=SAM
/FILE #STAB.PLOT.16,LINK=DSET33,FCBTYPE=SAM
/FILE #STAB.PLOT.17,LINK=DSET34,FCBTYPE=SAM
/EXEC OBJ.STAB
/RELEASE DSET15
/RELEASE DSET16
/RELEASE DSET17
/RELEASE DSET18
/RELEASE DSET19
/RELEASE DSET20
/RELEASE DSET21
/RELEASE DSET22
/RELEASE DSET23
/RELEASE DSET24
/RELEASE DSET25
/RELEASE DSET26
/RELEASE DSET27
/RELEASE DSET28
/RELEASE DSET29
/RELEASE DSET30
/RELEASE DSET31
/RELEASE DSET32
/RELEASE DSET33
/RELEASE DSET34
/ENDP

↑ Seitenanfang

Beispiel für eine Ergebnisdatei STAB.DTA

DATEN ZUR BEURTEILUNG DER STABILITAETSGRENZE FUER AXIALVERDICHTER NACH DEM PROGRAMM STAB.SRC
VERSUCHSVERDICHTER VV94 MIT LE00 + 3.5 GRAD       VV94.FLE0.ODF
PUNKT     SPF         M           PIT
  1      1.0000     22.0000      2.7141
  2      1.0000     22.2000      2.6692
  3      1.0000     22.4000      2.6131
  4      1.0000     22.6000      2.5414
  5      1.0000     22.8000      2.4458
DATEN FUER DIE KRITERIEN VON LIEBLEIN UND TRAUPEL:
HI LE00
     ---------M1----------- ---------M2----------- ---------M3----------- ---------M4----------- ---------M5------------
STRL    R2  DEQ  PHI PSISTU    R2  DEQ  PHI PSISTU    R2  DEQ  PHI PSISTU    R2  DEQ  PHI PSISTU    R2  DEQ  PHI PSISTU
  1    0.12-1.00 0.65 0.00    0.12-1.00 0.66 0.00    0.12-1.00 0.67 0.00    0.12-1.00 0.68 0.00    0.12-1.00 0.68 0.00
  2    0.14-0.95 0.66 0.00    0.14-0.95 0.67 0.00    0.14-0.95 0.68 0.00    0.14-0.95 0.69 0.00    0.14-0.95 0.70 0.00
  3    0.15-0.90 0.66 0.00    0.15-0.90 0.67 0.00    0.15-0.90 0.68 0.00    0.15-0.90 0.69 0.00    0.15-0.90 0.70 0.00
  4    0.16-0.86 0.67 0.00    0.16-0.86 0.68 0.00    0.16-0.86 0.69 0.00    0.16-0.86 0.70 0.00    0.16-0.86 0.71 0.00
  5    0.18-0.81 0.67 0.00    0.18-0.81 0.68 0.00    0.18-0.81 0.69 0.00    0.18-0.81 0.70 0.00    0.18-0.81 0.71 0.00
  6    0.19-0.76 0.66 0.00    0.19-0.76 0.67 0.00    0.19-0.76 0.68 0.00    0.19-0.76 0.69 0.00    0.19-0.76 0.70 0.00
  7    0.20-0.69 0.65 0.00    0.20-0.69 0.66 0.00    0.20-0.69 0.67 0.00    0.20-0.69 0.68 0.00    0.20-0.69 0.68 0.00
  8    0.22-0.62 0.63 0.00    0.22-0.62 0.64 0.00    0.22-0.62 0.65 0.00    0.22-0.62 0.65 0.00    0.22-0.62 0.66 0.00
  9    0.24-0.54 0.60 0.00    0.24-0.54 0.61 0.00    0.24-0.54 0.61 0.00    0.24-0.54 0.62 0.00    0.24-0.54 0.63 0.00
INTEG  0.00 0.00 0.66 0.00    0.00 0.00 0.67 0.00    0.00 0.00 0.68 0.00    0.00 0.00 0.69 0.00    0.00 0.00 0.69 0.00
HI LA01
     ---------M1----------- ---------M2----------- ---------M3----------- ---------M4----------- ---------M5------------
STRL    R2  DEQ  PHI PSISTU    R2  DEQ  PHI PSISTU    R2  DEQ  PHI PSISTU    R2  DEQ  PHI PSISTU    R2  DEQ  PHI PSISTU
  1    0.13 1.60 0.74 0.00    0.13 1.57 0.75 0.00    0.13 1.54 0.77 0.00    0.13 1.51 0.78 0.00    0.13 1.49 0.80 0.00
  2    0.14 1.56 0.72 0.00    0.14 1.53 0.73 0.00    0.14 1.50 0.75 0.00    0.14 1.48 0.76 0.00    0.14 1.45 0.78 0.00
  3    0.15 1.54 0.70 0.00    0.15 1.51 0.71 0.00    0.15 1.48 0.73 0.00    0.15 1.46 0.74 0.00    0.15-1.44 0.76 0.00
  4    0.17 1.52 0.68 0.00    0.17 1.49 0.70 0.00    0.17 1.47 0.71 0.00    0.17-1.45 0.72 0.00    0.17-1.44 0.74 0.00
  5    0.18 1.50 0.66 0.00    0.18 1.48 0.68 0.00    0.18-1.46 0.69 0.00    0.18-1.45 0.70 0.00    0.18-1.43 0.72 0.00
  6    0.19 1.48 0.64 0.00    0.19-1.46 0.65 0.00    0.19-1.45 0.66 0.00    0.19-1.43 0.68 0.00    0.19-1.41 0.69 0.00
  7    0.20-1.46 0.61 0.00    0.20-1.45 0.62 0.00    0.20-1.43 0.63 0.00    0.20-1.41 0.64 0.00    0.20-1.39 0.65 0.00
  8    0.22-1.44 0.57 0.00    0.22-1.43 0.58 0.00    0.22-1.41 0.59 0.00    0.22-1.39 0.60 0.00    0.22-1.37 0.61 0.00
  9    0.23-1.43 0.52 0.00    0.23-1.41 0.53 0.00    0.23-1.39 0.54 0.00    0.23-1.37 0.55 0.00    0.23-1.35 0.56 0.00
INTEG  0.00 0.00 0.65 0.00    0.00 0.00 0.66 0.00    0.00 0.00 0.67 0.00    0.00 0.00 0.69 0.00    0.00 0.00 0.70 0.00
HI LE01
     ---------M1----------- ---------M2----------- ---------M3----------- ---------M4----------- ---------M5------------
STRL    R2  DEQ  PHI PSISTU    R2  DEQ  PHI PSISTU    R2  DEQ  PHI PSISTU    R2  DEQ  PHI PSISTU    R2  DEQ  PHI PSISTU
  1    0.14 1.43 0.72 0.51    0.14 1.40 0.74 0.49    0.14 1.38 0.77 0.46    0.14-1.36 0.79 0.43    0.14-1.35 0.82 0.39
  2    0.15 1.47 0.69 0.55    0.15 1.43 0.71 0.53    0.15 1.40 0.73 0.50    0.15-1.38 0.76 0.47    0.15-1.37 0.78 0.43
  3    0.16 1.49 0.67 0.58    0.16 1.46 0.69 0.56    0.16 1.42 0.71 0.53    0.16-1.40 0.73 0.50    0.16-1.38 0.76 0.47
  4    0.17 1.51 0.66 0.62    0.17 1.47 0.67 0.59    0.17 1.44 0.69 0.56    0.17-1.41 0.71 0.53    0.17-1.39 0.73 0.50
  5    0.18 1.53 0.64 0.65    0.18 1.49 0.65 0.62    0.18 1.45 0.67 0.59    0.18-1.43 0.69 0.56    0.18-1.40 0.71 0.53
  6    0.19 1.57 0.62 0.67    0.19 1.53 0.63 0.65    0.19 1.49 0.65 0.62    0.19-1.45 0.66 0.59    0.19-1.43 0.68 0.55
  7    0.21 1.64 0.60 0.70    0.21 1.59 0.61 0.68    0.21 1.54 0.62 0.65    0.21 1.50 0.63 0.62    0.21-1.47 0.65 0.58
  8    0.22 1.74 0.58 0.72    0.22 1.69 0.59 0.70    0.22 1.64 0.60 0.67    0.22 1.59 0.61 0.64    0.22 1.54 0.62 0.60
  9    0.23 1.92 0.58 0.74    0.23 1.86 0.58 0.71    0.23 1.80 0.59 0.68    0.23 1.74 0.60 0.65    0.23 1.68 0.61 0.62
INTEG  0.00 0.00 0.63 0.65    0.00 0.00 0.65 0.63    0.00 0.00 0.66 0.60    0.00 0.00 0.68 0.57    0.00 0.00 0.70 0.53
HI LA02
     ---------M1----------- ---------M2----------- ---------M3----------- ---------M4----------- ---------M5------------
STRL    R2  DEQ  PHI PSISTU    R2  DEQ  PHI PSISTU    R2  DEQ  PHI PSISTU    R2  DEQ  PHI PSISTU    R2  DEQ  PHI PSISTU
  1    0.15 1.59 0.63 0.00    0.15 1.53 0.65 0.00    0.15 1.47 0.67 0.00    0.15-1.43 0.70 0.00    0.15-1.40 0.73 0.00
  2    0.16 1.62 0.62 0.00    0.16 1.55 0.64 0.00    0.16 1.50 0.66 0.00    0.16-1.45 0.69 0.00    0.16-1.42 0.71 0.00
  3    0.17 1.63 0.61 0.00    0.17 1.57 0.63 0.00    0.17 1.52 0.65 0.00    0.16 1.47 0.67 0.00    0.16-1.44 0.70 0.00
  4    0.18 1.64 0.60 0.00    0.17 1.59 0.62 0.00    0.17 1.53 0.63 0.00    0.17 1.49 0.65 0.00    0.17-1.46 0.68 0.00
  5    0.19 1.66 0.59 0.00    0.19 1.60 0.61 0.00    0.18 1.55 0.62 0.00    0.18 1.51 0.64 0.00    0.18-1.48 0.66 0.00
  6    0.20 1.68 0.58 0.00    0.20 1.63 0.59 0.00    0.20 1.59 0.61 0.00    0.20 1.54 0.62 0.00    0.19-1.50 0.64 0.00
  7    0.21 1.69 0.57 0.00    0.21 1.65 0.58 0.00    0.21 1.61 0.59 0.00    0.21 1.57 0.61 0.00    0.21 1.53 0.62 0.00
  8    0.22 1.65 0.55 0.00    0.22 1.62 0.56 0.00    0.22 1.59 0.57 0.00    0.22 1.56 0.59 0.00    0.22 1.53 0.60 0.00
  9    0.23 1.51 0.53 0.00    0.23 1.50 0.54 0.00    0.23-1.49 0.55 0.00    0.23-1.48 0.56 0.00    0.23-1.46 0.57 0.00
INTEG  0.00 0.00 0.59 0.00    0.00 0.00 0.60 0.00    0.00 0.00 0.62 0.00    0.00 0.00 0.63 0.00    0.00 0.00 0.65 0.00
HI LE02
     ---------M1----------- ---------M2----------- ---------M3----------- ---------M4----------- ---------M5------------
STRL    R2  DEQ  PHI PSISTU    R2  DEQ  PHI PSISTU    R2  DEQ  PHI PSISTU    R2  DEQ  PHI PSISTU    R2  DEQ  PHI PSISTU
  1    0.15 1.70 0.57 0.73    0.15 1.62 0.60 0.72    0.15 1.54 0.63 0.69    0.15 1.48 0.67 0.67    0.15-1.45 0.71 0.63
  2    0.16 1.73 0.57 0.75    0.16 1.65 0.59 0.73    0.16 1.58 0.62 0.71    0.16 1.51 0.65 0.68    0.16-1.46 0.69 0.65
  3    0.17 1.75 0.57 0.75    0.17 1.68 0.59 0.74    0.17 1.60 0.62 0.72    0.17 1.53 0.64 0.69    0.17-1.48 0.67 0.66
  4    0.18 1.76 0.58 0.76    0.18 1.69 0.59 0.74    0.18 1.62 0.61 0.72    0.18 1.55 0.63 0.70    0.18-1.49 0.66 0.67
  5    0.19 1.75 0.58 0.76    0.19 1.69 0.59 0.75    0.19 1.63 0.61 0.73    0.19 1.57 0.62 0.71    0.19 1.51 0.65 0.67
  6    0.20 1.75 0.57 0.77    0.20 1.70 0.59 0.75    0.20 1.64 0.60 0.74    0.20 1.58 0.62 0.71    0.20 1.53 0.63 0.68
  7    0.21 1.74 0.57 0.77    0.21 1.70 0.58 0.76    0.21 1.65 0.59 0.75    0.21 1.59 0.61 0.72    0.21 1.54 0.62 0.69
  8    0.22 1.74 0.57 0.78    0.22 1.70 0.57 0.77    0.22 1.65 0.58 0.76    0.22 1.60 0.60 0.73    0.22 1.55 0.61 0.70
  9    0.23 1.78 0.57 0.80    0.23 1.74 0.57 0.79    0.23 1.70 0.58 0.78    0.23 1.65 0.59 0.76    0.23 1.60 0.60 0.73
INTEG  0.00 0.00 0.57 0.76    0.00 0.00 0.59 0.75    0.00 0.00 0.60 0.73    0.00 0.00 0.62 0.71    0.00 0.00 0.64 0.68
HI LA03
     ---------M1----------- ---------M2----------- ---------M3----------- ---------M4----------- ---------M5------------
STRL    R2  DEQ  PHI PSISTU    R2  DEQ  PHI PSISTU    R2  DEQ  PHI PSISTU    R2  DEQ  PHI PSISTU    R2  DEQ  PHI PSISTU
  1    0.15 2.23 0.53 0.00    0.15 2.06 0.56 0.00    0.15 1.90 0.59 0.00    0.15 1.76 0.63 0.00    0.15 1.62 0.67 0.00
  2    0.16 2.10 0.54 0.00    0.16 1.98 0.56 0.00    0.16 1.85 0.59 0.00    0.16 1.73 0.62 0.00    0.16 1.62 0.65 0.00
  3    0.17 2.01 0.54 0.00    0.17 1.92 0.56 0.00    0.17 1.82 0.58 0.00    0.17 1.72 0.61 0.00    0.17 1.62 0.64 0.00
  4    0.18 1.93 0.55 0.00    0.18 1.86 0.56 0.00    0.18 1.79 0.58 0.00    0.18 1.70 0.60 0.00    0.18 1.62 0.63 0.00
  5    0.19 1.87 0.55 0.00    0.19 1.81 0.56 0.00    0.19 1.75 0.58 0.00    0.19 1.68 0.60 0.00    0.19 1.61 0.62 0.00
  6    0.20 1.80 0.55 0.00    0.20 1.76 0.56 0.00    0.20 1.71 0.58 0.00    0.20 1.65 0.59 0.00    0.20 1.59 0.61 0.00
  7    0.21 1.73 0.55 0.00    0.21 1.70 0.56 0.00    0.21 1.66 0.57 0.00    0.21 1.61 0.59 0.00    0.21-1.57 0.60 0.00
  8    0.22 1.64 0.54 0.00    0.22 1.62 0.55 0.00    0.22 1.59 0.56 0.00    0.22 1.56 0.57 0.00    0.22-1.53 0.59 0.00
  9    0.23-1.52 0.52 0.00    0.23-1.51 0.53 0.00    0.23-1.50 0.54 0.00    0.23-1.49 0.55 0.00    0.23-1.47 0.56 0.00
INTEG  0.00 0.00 0.55 0.00    0.00 0.00 0.56 0.00    0.00 0.00 0.58 0.00    0.00 0.00 0.60 0.00    0.00 0.00 0.62 0.00
HI LE03
     ---------M1----------- ---------M2----------- ---------M3----------- ---------M4----------- ---------M5------------
STRL    R2  DEQ  PHI PSISTU    R2  DEQ  PHI PSISTU    R2  DEQ  PHI PSISTU    R2  DEQ  PHI PSISTU    R2  DEQ  PHI PSISTU
  1    0.16 2.11 0.45 0.81    0.16 1.97 0.48 0.80    0.16 1.83 0.52 0.79    0.16 1.71 0.57 0.77    0.16 1.60 0.62 0.74
  2    0.17 2.09 0.48 0.82    0.17 1.97 0.51 0.81    0.17 1.85 0.54 0.80    0.16 1.73 0.57 0.78    0.16 1.61 0.61 0.76
  3    0.17 2.05 0.51 0.82    0.17 1.95 0.53 0.81    0.17 1.85 0.55 0.80    0.17 1.74 0.58 0.78    0.17 1.63 0.61 0.76
  4    0.18 2.00 0.53 0.81    0.18 1.92 0.54 0.81    0.18 1.83 0.56 0.80    0.18 1.74 0.58 0.78    0.18 1.64 0.61 0.75
  5    0.19 1.94 0.54 0.81    0.19 1.88 0.55 0.80    0.19 1.81 0.56 0.79    0.19 1.73 0.58 0.78    0.19 1.64 0.61 0.75
  6    0.20 1.89 0.55 0.80    0.20 1.84 0.55 0.80    0.20 1.78 0.56 0.79    0.20 1.72 0.58 0.77    0.20 1.64 0.60 0.75
  7    0.21 1.86 0.55 0.80    0.21 1.82 0.55 0.80    0.21 1.77 0.56 0.79    0.21 1.71 0.57 0.77    0.21 1.64 0.59 0.75
  8    0.22 1.87 0.54 0.81    0.22 1.83 0.54 0.80    0.22 1.79 0.55 0.80    0.22 1.73 0.56 0.78    0.22 1.66 0.57 0.75
  9    0.23 1.98 0.52 0.83    0.23 1.95 0.53 0.83    0.23 1.90 0.53 0.83    0.23 1.85 0.54 0.81    0.23 1.77 0.55 0.79
INTEG  0.00 0.00 0.53 0.81    0.00 0.00 0.54 0.80    0.00 0.00 0.56 0.79    0.00 0.00 0.58 0.78    0.00 0.00 0.60 0.75
HI LA04
     ---------M1----------- ---------M2----------- ---------M3----------- ---------M4----------- ---------M5------------
STRL    R2  DEQ  PHI PSISTU    R2  DEQ  PHI PSISTU    R2  DEQ  PHI PSISTU    R2  DEQ  PHI PSISTU    R2  DEQ  PHI PSISTU
  1    0.16 2.96 0.45 0.00    0.16 2.65 0.48 0.00    0.16 2.37 0.52 0.00    0.16 2.10 0.56 0.00    0.16 1.86 0.61 0.00
  2    0.17 2.48 0.48 0.00    0.16 2.32 0.50 0.00    0.16 2.14 0.53 0.00    0.16 1.97 0.56 0.00    0.16 1.79 0.60 0.00
  3    0.17 2.22 0.50 0.00    0.17 2.12 0.52 0.00    0.17 2.01 0.54 0.00    0.17 1.88 0.57 0.00    0.17 1.74 0.60 0.00
  4    0.18 2.04 0.52 0.00    0.18 1.98 0.53 0.00    0.18 1.90 0.55 0.00    0.18 1.81 0.57 0.00    0.18 1.70 0.60 0.00
  5    0.19 1.91 0.53 0.00    0.19 1.87 0.54 0.00    0.19 1.82 0.55 0.00    0.19 1.75 0.57 0.00    0.19 1.66 0.60 0.00
  6    0.20 1.81 0.54 0.00    0.20 1.78 0.55 0.00    0.20 1.74 0.56 0.00    0.19 1.69 0.57 0.00    0.19 1.62 0.60 0.00
  7    0.20 1.72 0.54 0.00    0.20 1.70 0.55 0.00    0.20 1.68 0.56 0.00    0.20 1.64 0.57 0.00    0.20 1.58 0.59 0.00
  8    0.21 1.62 0.54 0.00    0.21 1.61 0.54 0.00    0.21 1.60 0.55 0.00    0.21 1.57 0.56 0.00    0.21 1.53 0.58 0.00
  9    0.22 1.49 0.52 0.00    0.22 1.49 0.53 0.00    0.22 1.49 0.53 0.00    0.22-1.48 0.54 0.00    0.22-1.46 0.56 0.00
INTEG  0.00 0.00 0.52 0.00    0.00 0.00 0.54 0.00    0.00 0.00 0.55 0.00    0.00 0.00 0.57 0.00    0.00 0.00 0.59 0.00
HI LE04
     ---------M1----------- ---------M2----------- ---------M3----------- ---------M4----------- ---------M5------------
STRL    R2  DEQ  PHI PSISTU    R2  DEQ  PHI PSISTU    R2  DEQ  PHI PSISTU    R2  DEQ  PHI PSISTU    R2  DEQ  PHI PSISTU
  1    0.16 2.63 0.34 0.81    0.16 2.40 0.38 0.81    0.16 2.19 0.43 0.81    0.16 1.99 0.47 0.80    0.16 1.79 0.53 0.77
  2    0.17 2.45 0.43 0.81    0.17 2.28 0.45 0.81    0.16 2.12 0.48 0.80    0.16 1.95 0.51 0.79    0.16 1.77 0.55 0.77
  3    0.17 2.27 0.49 0.79    0.17 2.16 0.50 0.79    0.17 2.04 0.51 0.79    0.17 1.90 0.53 0.78    0.17 1.75 0.57 0.76
  4    0.18 2.13 0.52 0.77    0.18 2.05 0.53 0.77    0.18 1.96 0.54 0.77    0.18 1.86 0.55 0.76    0.18 1.73 0.58 0.74
  5    0.19 2.01 0.54 0.74    0.19 1.96 0.55 0.75    0.19 1.89 0.55 0.75    0.19 1.81 0.57 0.74    0.19 1.70 0.59 0.72
  6    0.20 1.92 0.56 0.72    0.19 1.88 0.56 0.72    0.19 1.83 0.57 0.72    0.19 1.76 0.58 0.72    0.19 1.67 0.60 0.69
  7    0.20 1.85 0.57 0.70    0.20 1.82 0.57 0.70    0.20 1.78 0.58 0.70    0.20 1.73 0.58 0.69    0.20 1.65 0.60 0.67
  8    0.21 1.82 0.58 0.68    0.21 1.80 0.58 0.68    0.21 1.77 0.58 0.68    0.21 1.72 0.59 0.68    0.21 1.65 0.60 0.65
  9    0.22 1.86 0.59 0.67    0.22 1.84 0.59 0.68    0.22 1.81 0.59 0.68    0.22 1.76 0.60 0.67    0.22 1.69 0.61 0.65
INTEG  0.00 0.00 0.54 0.74    0.00 0.00 0.54 0.74    0.00 0.00 0.55 0.74    0.00 0.00 0.56 0.73    0.00 0.00 0.59 0.71
                          ---------M1------- ---------M2------- ---------M3------- ---------M4------- ---------M5-------
KOCHKRITERIUM:               CHZUL    CH        CHZUL    CH        CHZUL    CH        CHZUL    CH        CHZUL   CH
STUFE AUS LA01 UND LE01      0.444   0.350      0.444   0.335      0.444   0.318      0.444   0.300      0.444   0.279
STUFE AUS LA02 UND LE02      0.439   0.415      0.439   0.405      0.440   0.392      0.440   0.376      0.440   0.356
STUFE AUS LA03 UND LE03      0.426   0.453      0.427   0.447      0.427   0.438      0.427   0.425      0.427   0.406
STUFE AUS LA04 UND LE04      0.421   0.431      0.421   0.431      0.422   0.427      0.422   0.418      0.422   0.401
                          ---------M1------- ---------M2------- ---------M3------- ---------M4------- ---------M5-------
ETAS DER BESCHAUFELUNG ==>        0.9294             0.9307             0.9316             0.9315             0.9293

STABILITAETSGRENZE:
NACH LIEBLEIN INSTABIL BIS ML =  22.200 KG/S UND PIT =   2.669  HI LE04   (NAECHST GROESSERES VORGEGEBENES M IST STABIL)
NACH   KOCH   GRENZE   BEI MK =  22.576 KG/S UND PIT =   2.551  STUFE AUS LA03 UND LE03
NACH  TRAUPEL GRENZE   BEI MT =  22.310 KG/S UND PIT =   2.640  STUFE AUS LA04 UND LE04
NACH  ETASMAX GRENZE   BEI MW =  22.476 KG/S UND PIT =   2.589

↑ Seitenanfang

Übersicht

English Fluid Technology
English Web Design
English Designer
Deutsch Strömungsmechanik